By Bogdan Coroi
#309143
Fernando Tella
1. [DONE] Pack'n Go Script. Here's the script.

JTB
1. [DONE]I use clipmaps a lot and I need to have the "alpha only" option from MXED inside MAX mat editor... If it is already there, I can't find it...

sandykoufax:
1. [NOT POSSIBLE] Shift Lens viewport support
2. [NOT POSSIBLE] Camera sensor presets
3. easy preview object selector ( Mihnea says he will find a better solution )
4. [DONE]bitmap viewer (like max default 'view image' button )
5. [NOT POSSIBLE] when change Standard material to Maxwell material, [replace material ] popup remove. I think it's useless.
6. [DONE] In max preference, material preview default render time is 30sec and it's shortest setting, so I cannot lower to 10sec.
7. [DONE] copy/paste bitmap between standard material and maxwell material. When using 1.71 plugins, I could drag n drop or copy/paste the bitmap on the standard diffuse slot to maxwell reflectance slot. but in 2.0 plugins, I cannot doing it.
7-1. [DONE] bitmap drag & drop from explorer. It's a related wishlist with 7.
By JTB
#311660
Let's not open a thread for each wish.... So, here is a small one...

I use clipmaps a lot and I need to have the "alpha only" option from MXED inside MAX mat editor... If it is already there, I can't find it...
User avatar
By Mihnea Balta
#311786
The camera presets in studio are just various film (sensor) sizes. As Max has a global horizontal aperture setting in the common render parameters panel, it doesn't make too much sense to add these presets, because they wouldn't work per camera anyway. They would also have to modify the field of view and image aspect ratio of the selected camera, because the vertical aperture is not specified explicitly in Max, but computed automatically based on those values.

Tone mapping has nothing to do with it.
User avatar
By Fernando Tella
#314648
I would like to have a way of collecting all the referenced mxm's used in a scene. When moving to another network there's no way of collecting them (I can do it by hand, but it's painful); I can get the textures making a Pack&go from studio, but not the mxm's.

Thanks!
User avatar
By Fernando Tella
#314653
A pack&go collects mxs and textures, as at studio the materials are always embeded; but when working from max we can use embeded or referenced materials. If you use embeded materials you only need to collect textures, but if you use referenced you need the mxm files too and there's no fast way to take them all.
Does it makes sense?

Cheers!
By Bogdan Coroi
#314654
Ah, I thought you mean Studio can't handle mxms in a pack&go process. OK, I think I get it now. You need a way to get all referenced mxm from a 3dsmax scene and put them in a directory basically, right? A pack&go simulation for mxms.
By Bogdan Coroi
#314671
Assuming this is what you wanted, I wrote a simple script that copies all mxm files found in referenced materials to a given directory. Also, there is a checkbox which controls if you want to change the path in all referenced materials to point to the new directory.

Copy&Paste the code in a .ms file and execute it in 3dsmax. A dialog will open and then everything is straightforward:
Code: Select all
function translateReferenced mtl newDir fixPath =
(
   newFile = newDir+ "\\" + filenameFromPath mtl.filename
   copyfile mtl.filename newFile
   
   if (fixPath == true) do
      mtl.filename = newFile
)

function walkMultiMat multiMat newDir fixPath =
(
   numSubMat = getNumSubMtls multiMat
   for idx = 1 to numSubMat do
   (
      subMat = getSubMtl multiMat idx
      if (subMat == undefined) do
         continue

      if (subMat.classID[1] == 837576131 and subMat.classID[2] == 1983282922) do
      (   
         translateReferenced subMat newDir fixPath
      )

      if subMat.classID[1] == 512 do
         walkMultiMat subMat newDir fixPath
   )
)

rollout MaxwellGetRefMaterials "Maxwell 2.0 Referenced Material Collector"
(
   edittext dir_text "MXM Destination Directory:" fieldWidth:265 labelOnTop:true
   button dir_browse "..." align:#right offset:[0,-23]
   checkbox fixpath_checkbox "Update MXM path in all materials"
   button doit "Process Scene"
   progressbar doit_prog color:blue
   label obj_label "Objects to be processed"
   
   on dir_browse pressed do
   (
      print dir_text.text
      newPath = getSavePath caption:"Choose a directory to place all mxm files" initialDir: dir_text.text
      if (newPath != undefined) do
         dir_text.text = newPath
   )
   
   on MaxwellGetRefMaterials open do
   (
      dir_text.text = sysinfo.currentdir
   )
   
   on doit pressed do
   (
      i = 0
      select $**
      for obj in selection do
      (
         objMtl = obj.material
         if (objMtl == undefined) do
            continue
         
         if (objMtl.classID[1] == 837576131 and objMtl.classID[2] == 1983282922) do
         (
            translateReferenced objMtl dir_text.text fixpath_checkbox.state
         )
            
         i = i + 1
         doit_prog.value = 100.*i/selection.count
         obj_label.text = obj.name
         
         if obj.material.classID[1] == 512 do
            walkMultiMat obj.material dir_text.text fixpath_checkbox.state
      )
      
      obj_label.text = "Finished"
   )
)

createDialog MaxwellGetRefMaterials 320 140 
LE: Updated the script because of a bug.
Sketchup 2019.2

Same issue here, immediate bugsplat on export of a[…]

Moving license to a new computer?

I have the same problem. I've never had trouble ac[…]

Diamond DA42

That fuselage looks nicely resolved, well done to […]

Plugin Request Thread

What with the huge increase in AI, making our dear[…]